SUPPLEMENTARY FILE:


MPLUS INPUT 1: PATTERNS OF LIFESTYLE BEHAVIORS IN ADOLESCENCE: LATENT CLASS MODEL - 5-CLASS SOLUTION

MPLUS INPUT 2: MEAN DIFFERENCES IN BIOGICAL AGING BETWEEN THE LIFESTYLE BEHAVIOR PATTERNS: BCH-APPROACH (EXAMPLE: MODEL FOR DUNEDINPACE)

MPLUS INPUT 3: SAVE THE RESIDUALS OF THE SECONDARY MODEL(FACTOR SCORES) (EXAMPLE: MODEL FOR DUNEDINPACE)

SPSS SYNTAX: CONVERT THE FACTOR SCORES BACK TO ORIGINAL SCALE, CONVERT DATA TO A WIDE FORMAT AND SAVE DATA AS DAT-FILE

MPLUS INPUT 4: GENETIC AND ENVIRONMENTAL INFLUENCES ON BIOLOGICAL AGING (EXAMPLE: MODEL FOR DUNEDINPACE)
               THE MODEL INCLUDING ADDITIVE GENETIC AND NON-SHARED ENVIRONMENTAL COMPONENT (AE-MODEL)

MPLUS INPUT 5: GENETIC AND ENVIRONMENTAL INFLUENCES ON THE RESIDUAL TERM (EXAMPLE: MODEL FOR DUNEDINPACE)
               THE MODEL INCLUDING ADDITIVE GENETIC AND NON-SHARED ENVIRONMENTAL COMPONENT (AE-MODEL)


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!MPLUS INPUT 1: PATTERNS OF LIFESTYLE BEHAVIORS IN ADOLESCENCE: LATENT CLASS MODEL - 5-CLASS SOLUTION
!The classification is based on BMI and LTPA at ages 12, 14 and 17 years 
!and smoking status and alcohol use at ages 14 and 17 years (10 indicator variables). 
!Bolck–Croon–Hagenaars (BCH)-weights and auxiliary variables are saved

!Note. Starting values for the model parameters are specified using asterix (*) to obtain 
!a solution in which the order of the classes is the same as in the manuscript 


DATA:
  FILE IS "data_FinnTwin12_clocks.dat";

VARIABLE:
  NAMES ARE ...;


USEVARIABLES ARE                                          !Lifestyle-related factors in adolescence:
bmi12 bmi14 bmi17                                         !Body mass index 
ltpa12 ltpa14 ltpa17                                      !Physical activity
smo14 smo17                                               !Smoking
alcoh14 alcoh17;                                          !Alcohol use
 
CATEGORICAL ARE  
ltpa12 ltpa14 ltpa17                                      
smo14 smo17             
alcoh14 alcoh17;

AUXILIARY ARE                                              
personid 
ZYG2                                                      !zygosity (1=monozygotic, 2=dizygotic)
sex age pube12                                            !Potential confounding variables sex (female=1, male=0), age and baseline pubertal development (PDS)
DNAmRes HanRes PhenoRes GrimRes  dunedin pace             !Epigenetic aging measures (AA Horvath, AA Hannum, AA PhenoAge, AA GrimAge, DunedinPoAm, DunedinPACE)
RDNAm RHan Rpheno RGrim Rdunedin Rpace                    !Epigenetic aging measures adjusted for sex, age and baseline pubertal development 
ADM B2M CystC GDF15 Leptin PACKYRS PAI1 TIMP1             !Age-adjusted DNAm-based plasma proteins and smoking pack-years
smoking alcohol bmi sport;                                !Lifestyle-related factors in adulthood

cluster is familyid;
CLASSES C(5);                                             !5-class solution
MISSING ARE ALL (-999);

ANALYSIS:
TYPE IS MIXTURE COMPLEX;
STARTS 1000 40;
ESTIMATOR=MLR;

MODEL:

%OVERALL%
[bmi12  bmi14  bmi17]  ;
bmi12 bmi14 bmi17;

[ltpa12$1 ltpa14$1  ltpa17$1
smo14$1  smo17$1 alcoh14$1  alcoh17$1];

[ltpa12$2  ltpa14$2  ltpa17$2
smo14$2  smo17$2 alcoh14$2 alcoh17$2 ];

[ ltpa14$3  ltpa17$3
smo14$3  smo17$3  alcoh14$3 alcoh17$3];




%C#1%
  
[bmi12*17  bmi14*19  bmi17*20]  ;   !Means
bmi12*1 bmi14*1 bmi17*1;            !variances

[LTPA12$1*-0.9];                    !Thresholds for the categirical variables
[LTPA12$2*1.6];
[LTPA14$1*-2.4];
[LTPA14$2*-1.3];
[LTPA14$3*1];
[LTPA17$1*-2.2];
[LTPA17$2*-1.1];
[LTPA17$3*1.1];
[SMO14$1*4.8];
[SMO14$2*15];
[SMO14$3*15.1];
[SMO17$1*0.8];
[SMO17$2*1.5];
[SMO17$3*1.9];
[ALCOH14$1*2];
[ALCOH14$2*4.4];
[ALCOH14$3*6.3];
[ALCOH17$1*-1.3];
[ALCOH17$2*0.8];
[ALCOH17$3*3.3];


%C#2%
  
[bmi12*15  bmi14*16  bmi17*18]  ;
BMI12*1 BMI14*1 BMI17*1;


[LTPA12$1*-0.2];
[LTPA12$2*2.3];
[LTPA14$1*-1.6];
[LTPA14$2*-0.5];
[LTPA14$3*1.5];
[LTPA17$1*-1.5];
[LTPA17$2*-0.5];
[LTPA17$3*1.5];
[SMO14$1*3.6];
[SMO14$2*4.8];
[SMO14$3*6.2];
[SMO17$1*1];
[SMO17$2*1.5];
[SMO17$3*1.8];
[ALCOH14$1*2.7];
[ALCOH14$2*4.1];
[ALCOH14$3*7.7];
[ALCOH17$1*-0.7];
[ALCOH17$2*1.3];
[ALCOH17$3*3.2];


%C#3%
  
[bmi12*19  bmi14*20  bmi17*22]  ;
bmi12*2 bmi14*2 bmi17*2;

[LTPA12$1*-0.6];
[LTPA12$2*1.8];
[LTPA14$1*-1.8];
[LTPA14$2*-0.8];
[LTPA14$3*1.5];
[LTPA17$1*-1.9];
[LTPA17$2*-0.9];
[LTPA17$3*1.4];
[SMO14$1*3.6];
[SMO14$2*5.5];
[SMO14$3*15];
[SMO17$1*0.8];
[SMO17$2*1.4];
[SMO17$3*1.6];
[ALCOH14$1*1.7];
[ALCOH14$2*3.6];
[ALCOH14$3*15];
[ALCOH17$1*-1.3];
[ALCOH17$2*0.8];
[ALCOH17$3*3.3];


%C#4%
  
[bmi12*23  bmi14*25  bmi17*27]  ;
bmi12 bmi14 bmi17;

[LTPA12$1*-0.2];
[LTPA12$2*2.2];
[LTPA14$1*-1.5];
[LTPA14$2*-0.4];
[LTPA14$3*1.6];
[LTPA17$1*-1];
[LTPA17$2*-0.2];
[LTPA17$3*2.1];
[SMO14$1*1.6];
[SMO14$2*2.5];
[SMO14$3*3.3];
[SMO17$1*0];
[SMO17$2*0.5];
[SMO17$3*0.7];
[ALCOH14$1*1.2];
[ALCOH14$2*2.8];
[ALCOH14$3*5.6];
[ALCOH17$1*-1.2];
[ALCOH17$2*0.6];
[ALCOH17$3*2.5];

%C#5%
  
[bmi12*17  bmi14*18  bmi17*20]  ;
bmi12 bmi14 bmi17;

[LTPA12$1*-0.3];
[LTPA12$2*2.1];
[LTPA14$1*-1];
[LTPA14$2*-0.1];
[LTPA14$3*1.8];
[LTPA17$1*-0.6];
[LTPA17$2*0.1];
[LTPA17$3*2.2];
[SMO14$1*-0.7];
[SMO14$2*0.5];
[SMO14$3*1.1];
[SMO17$1*-3.4];
[SMO17$2*-1.5];
[SMO17$3*-1.1];
[ALCOH14$1*-1.2];
[ALCOH14$2*0.8];
[ALCOH14$3*3.2];
[ALCOH17$1*-4.8];
[ALCOH17$2*-1];
[ALCOH17$3*1.2];

OUTPUT: SAMP STAND RES MOD(4) CINT
TECH11 ;

PLOT: TYPE IS PLOT1 PLOT2 PLOT3;
SERIES IS bmi12 (0) bmi14 (1) bmi17 (2);

SAVE: FILE IS BCHWEIGHTS_5.dat;                             !Save BCH-weights and auxiliary variables in the same datafile.                     
SAVE=BCHWEIGHTS;
MISSFLAG=-999;
FORMAT f20.3;
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!




!MPLUS INPUT 2: MEAN DIFFERENCES IN BIOGICAL AGING BETWEEN THE LIFESTYLE BEHAVIOR PATTERNS: BCH-APPROACH (EXAMPLE: MODEL FOR DUNEDINPACE)


DATA:
  FILE IS "BCHWEIGHTS_5.dat";                                !Dataset obtained from the previous analysis run (Mplus input 1)

VARIABLE:
  NAMES ARE 
    ltpa12 ltpa14 ltpa17         
    SMO14 SMO17 alcoh14 alcoh17          
    BMI12 BMI14 BMI17          
    PERSONID       
    ZYG  SEX AGE PUBE12               
    DNAMRES HANRES PHENORES GRIMRES        
    DUNEDIN PACE        
    RDNAM RHAN RPHENO RGRIM RDUNEDIN RPACE                   
    ADM B2M CYSTC GDF15 LEPTIN PACKYRS PAI1 TIMP1          
    SMOKING  ALCOHOL BMI SPORT          
    BCHW1 BCHW2 BCHW3 BCHW4 BCHW5                            !BCH-WEIGHTS
    CPROB1 CPROB2 CPROB3 CPROB4 CPROB5                       !Posterior probabilities
    C                                                        !Classification of individuals based on their most likely latent class membership
    FAMILYID      ;


USEVARIABLES ARE  PACE  BCHW1 BCHW2 BCHW3 BCHW4 BCHW5
    sex age pube12 ;

SUBPOPULATION IS (PACE NE -999);

Training= BCHW1 BCHW2 BCHW3 BCHW4 BCHW5 (bch);

CLUSTER IS familyid;

Classes = C(5);
MISSING ARE ALL (-999);


DEFINE:
STANDARDIZE age pube12 ;

ANALYSIS:
TYPE IS MIXTURE COMPLEX;
STARTS=0;
ESTIMATOR=MLR;



MODEL:

%OVERALL%

[PACE];
PACE ON sex age pube12 ;                                     !The model is adjusted for sex, age and baseline pubertal development
sex WITH age pube12 ;
age WITH pube12;


%C#1%
[PACE] (c1);
PACE;


%C#2%
[PACE] (c2);
PACE;

%C#3%
[PACE] (c3);
PACE;

%C#4%
[PACE] (c4);
PACE;


%C#5%
[PACE] (c5);
PACE;


MODEL CONSTRAINT:                                           
NEW( e1 e2 e3 e4 e5 e6 e7 e8 e9 e10 );          !Mean differences in biological aging
e1=(c1-c2); 
e2=(c1-c3);
e3=(c1-c4);
e4=(c1-c5);
e5=(c2-c3);
e6=(c2-c4);
e7=(c2-c5);
e8=(c3-c4);
e9=(c3-c5);
e10=(c4-c5);


!MODEL TEST:                                     !To obtain Wald-test replace the model constraint -lines with the model test -lines
!0=c1-c2;
!0=c1-c3;
!0=c1-c4;
!0=c1-c5;


OUTPUT: SAMP STAND RES MOD(4) CINT;


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

!MPLUS INPUT 3: SAVE THE RESIDUALS OF THE SECONDARY MODEL (FACTOR SCORES) (EXAMPLE: MODEL FOR DUNEDINPACE)
              ! THE RESIDUAL TERM OF BIOLOGICAL AGING CORRESPONDS TO THE VARIATION IN BIOLOGICAL AGING NOT EXPLAINED 
              ! BY THE ADOLESCENT LIFESTYLE BEHAVIOR PATTERNS 

TITLE:  

DATA:
  FILE IS "BCHWEIGHTS_5.dat";

 
VARIABLE:
    ltpa12 ltpa14 ltpa17         
    SMO14 SMO17 alcoh14 alcoh17          
    BMI12 BMI14 BMI17          
    PERSONID       
    ZYG  SEX PUBE12 AGE               
    DNAMRES HANRES PHENORES GRIMRES        
    DUNEDIN PACE        
    RDNAM RHAN RPHENO RGRIM RDUNEDIN RPACE                   
    ADM B2M CYSTC GDF15 LEPTIN PACKYRS PAI1 TIMP1          
    SMOKING  ALCOHOL BMI SPORT          
    BCHW1 BCHW2 BCHW3 BCHW4 BCHW5                            !BCH-WEIGHTS
    CPROB1 CPROB2 CPROB3 CPROB4 CPROB5                       !Classification probabilities
    C                                                        !Classification of individuals based on their most likely latent class membership
    FAMILYID      ;


USEVARIABLES ARE
RPACE BCHW1  BCHW2  BCHW3  BCHW4  BCHW5;


UEOBSERVATIONS ARE (RPACE NE -999);

CLASSES IS C(5);
MISSING ARE ALL (-999);

TRAINING=BCHW1 BCHW2 BCHW3 BCHW4 BCHW5 (BCH);

AUXILIARY IS PERSONID FAMILYID ZYG;

DEFINE: STANDARDIZE RPACE;

ANALYSIS:
TYPE IS MIXTURE;
ESTIMATOR=MLR;
STARTS=0;

MODEL:

%OVERALL%                                            


F1 by RPACE@1;                 !The residual term (latent variable) F1 corresponds to the variation in biological aging 
RPACE@0;                       !not explained by the adolescent lifestyle behavior patterns (C)
[RPACE];


%C#1%
  
[RPACE F1@0];
RPACE@0;
F1;

%C#2%
  
[RPACE F1@0];
RPACE@0;
F1;

%C#3%

[RPACE F1@0];
RPACE@0;
F1;


%C#4%

[RPACE F1@0];
RPACE@0;
F1;


%C#5%

[RPACE F1@0];
RPACE@0;
F1;


OUTPUT: SAMP STAND RES MOD(4) CINT ;
PLOT: TYPE IS PLOT1 PLOT2 PLOT3;

SAVE: FILE IS RESIT_RPACE_adj.DAT;
SAVE=FS;                                          !SAVE FACTOR SCORES
FORMAT F20.3;
missflag=-999;



!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


*SPSS SYNTAX:
*CONVERT THE FACTOR SCORES BACK TO ORIGINAL SCALE, CONVERT DATA TO A WIDE FORMAT AND SAVE AS DAT-FILE


*open the datafile obtained from the previous analysis run (Mplus input 3).

set decimal=dot.

DATA LIST FILE='U:\2_artikkeli\Full submission eLife\Mplus inputs\RESIT_RPACE_adj.DAT' FREE/
 RPACE  BCHW1   BCHW2  BCHW3  BCHW4   BCHW5  PERSONID   FAMILYID       
  ZYG2   F1  C_F1   CPROB1  CPROB2  CPROB3   CPROB4  CPROB5  C .

RECODE
RPACE  BCHW1   BCHW2  BCHW3  BCHW4   BCHW5  PERSONID   FAMILYID       
  ZYG2   F1  C_F1   CPROB1  CPROB2  CPROB3   CPROB4  CPROB5  C
 (-999=SYSMIS).
EXECUTE.

* regress DunedinPACE on the residual term F1 and save the predicted values.

REGRESSION  /MISSING LISTWISE  /STATISTICS COEFF OUTS R ANOVA  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN   /DEPENDENT RPACE  /METHOD=ENTER F1  /SAVE PRED.

* convert data to wide format. 

SORT CASES BY FAMILYID .
CASESTOVARS
  /ID=FAMILYID
  /GROUPBY=VARIABLE.

SAVE OUTFILE='U:\2_artikkeli\FinnTwin12_ajot\Kombi\RESIT_RPACE_wide.sav'.

RECODE
FAMILYID ZYG2 RPACE.1 RPACE.2 PERSONID.1 PERSONID.2 PRE_1.1 PRE_1.2
(SYSMIS=-999).
EXECUTE.

WRITE OUTFILE='U:\2_artikkeli\FinnTwin12_ajot\Kombi\final_RPACE.dat' ENCODING='ASCII'/
FAMILYID ZYG2 RPACE.1 RPACE.2 PERSONID.1 PERSONID.2 PRE_1.1 PRE_1.2 (8f20.3).
EXECUTE.

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


!MPLUS INPUT 4: GENETIC AND ENVIRONMENTAL INFLUENCES ON BIOLOGICAL AGING (EXAMPLE: MODEL FOR DUNEDINPACE)
!THE MODEL INCLUDING ADDITIVE GENETIC AND NON-SHARED ENVIRONMENTAL COMPONENT (AE-MODEL)

DATA:

FILE IS "final_RPACE.dat";                                   !Datafile in wide format


VARIABLE: NAMES ARE
FAMILYID ZYG RPACE1 RPACE2 id1 id2 F1 F2;

USEVARIABLES ARE RPACE1 RPACE2 ;
USEOBSERVATIONS ARE (RPACE1 NE -999) AND (RPACE2 NE -999);

GROUPING IS ZYG(1=Mz 2=Dz);

MISSING ARE ALL (-999);


DEFINE: 

ANALYSIS:
TYPE IS GENERAL;
ESTIMATOR IS MLR;


MODEL:

[RPACE1 RPACE2] ;
RPACE1@0;
RPACE2@0;


A1 BY RPACE1* (a);
E1 BY RPACE1* (e);

A2 BY RPACE2* (a);
E2 BY RPACE2* (e);

[A1-E2@0];
A1-E2@1;


A1 WITH A2@1; 
E1 WITH E2@0;

A1 WITH  E1@0 E2@0;
A2 WITH  E1@0 E2@0;


MODEL Dz:

[RPACE1 RPACE2];     
A1 WITH A2@0.5;
       

MODEL CONSTRAINT:

NEW(A2, E2,TOT);
TOT=(a*a+e*e);                                                                          !Total variance in biological aging (var_tot)          
A2=(a*a);                                                                               !The variance in biological aging explained by shared genetic factors
E2=(e*e);                                                                               !The variance in biological aging explained by unshared environmental factors  

OUTPUT: SAMP RES CINTERVAL;


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

 

!MPLUS INPUT 5: GENETIC AND ENVIRONMENTAL INFLUENCES ON RESIDUAL TERM (EXAMPE: MODEL FOR DUNEDINPACE)
!THE MODEL INCLUDING ADDITIVE GENETIC AND NON-SHARED ENVIRONMENTAL COMPONENT (AE-MODEL)

DATA:
   FILE IS "final_RPACE.dat"; 

VARIABLE: NAMES ARE
  FAMILYID ZYG RPACE1 RPACE2 id1 id2 F1 F2;

USEVARIABLES ARE F1 F2;

USEOBSERVATIONS ARE (RPACE1 NE -999 AND RPACE2 NE -999);

GROUPING IS ZYG(1=Mz 2=Dz);

MISSING ARE ALL (-999);


ANALYSIS:
  TYPE IS GENERAL;
  ESTIMATOR IS MLR;


MODEL:

[F1 F2] ;
F1@0;
F2@0;

A1 BY F1* (a);
E1 BY F1* (e);

A2 BY F2* (a);
E2 BY F2* (e);

[A1-E2@0];
A1-E2@1;
A1 WITH A2@1; 
E1 WITH E2@0;

A1 WITH  E1@0  E2@0;
A2 WITH  E1@0  E2@0;


MODEL Dz:

[F1 F2] ;
A1 WITH A2@0.5;

MODEL CONSTRAINT:
NEW(A2,  E2, TOT);

TOT=(a*a+e*e);                                    !Total variance in the residual of biological aging (Var_res)
A2=(a*a);                                         !The variance in the residual of biological aging explained by shared genetic factors
E2=(e*e);                                         !The variance in the residual of biological aging explained by unshared environmental factors  

OUTPUT: SAMP RES  CINTERVAL;